extends Node

var _jpg_path
var _png_path

signal cache_done


func _cache_error(err: String) -> String:
	return "CACHE::ERROR::" + err + "\n"


func _check_cache(id: String) -> bool:
	if !FileAccess.file_exists("user://card_cache/" + id + "/card.json"):
		return false
	if !FileAccess.file_exists("user://card_cache/" + id + "/card.png"):
		return false
	if !FileAccess.file_exists("user://card_cache/" + id + "/card.jpg"):
		return false
	return true


func fetch_card(id: String) -> void:
	if _check_cache(id):
		return

	await _do_http_request_card(id)
	await _do_http_request_imgs(id, _png_path, true)
	await _do_http_request_imgs(id, _jpg_path, false)
	cache_done.emit()


func _do_http_request_imgs(id: String, image_path: String, png: bool) -> void:
	var httpr = HTTPRequest.new()
	add_child(httpr)

	var headers = PackedStringArray(["User-Agent: MTGUntapClone/0.1", "Accept: */*"])
	var error = httpr.request(image_path, headers)
	if error != OK:
		push_error(_cache_error("GET_REQUEST") + "An error occurred in the Scryfall request.")
	var response = await httpr.request_completed

	var img = Image.new()
	var imgerr
	if png:
		imgerr = img.load_png_from_buffer(response[3])
	else:
		imgerr = img.load_jpg_from_buffer(response[3])
	if imgerr != OK:
		push_error(_cache_error("IMG_LOADING") + "Couldn't load the image.")

	img.save_png("user://card_cache/" + id + ("/card.png" if png else "/card.jpg"))
	img = null


func _do_http_request_card(id: String) -> void:
	var httpr = HTTPRequest.new()
	add_child(httpr)
	#httpr.request_completed.connect(_scryfall_card_response)
	var headers = PackedStringArray(["User-Agent: MTGUntapClone/0.1", "Accept: */*"])
	var error = httpr.request("https://api.scryfall.com/cards/" + id, headers)
	if error != OK:
		push_error(_cache_error("GET_REQUEST") + "An error occurred in the Scryfall request.")

	var response = await httpr.request_completed

	if response[0] != HTTPRequest.RESULT_SUCCESS:
		push_error(_cache_error("GET_REQUEST") + "Failed to fetch card data from Scryfall")
		return

	var unprocessed_body = response[3].get_string_from_utf8()
	var card_content = JSON.parse_string(unprocessed_body)
	if card_content == null:
		push_error(_cache_error("PARSING") + "Failed to parse the Scryfall card results.")

	var dir = DirAccess.open("user://")
	dir.make_dir_recursive("user://card_cache/" + id + "/")  # lets ensure the path is there
	dir = null

	var card_cache = FileAccess.open("user://card_cache/" + id + "/card.json", FileAccess.WRITE)
	card_cache.store_string(unprocessed_body)  # cache the json response
	card_cache = null  # closes the file

	var image_uris = card_content["image_uris"]
	_png_path = image_uris["png"]
	_jpg_path = image_uris["normal"]